Теперь, когда мы прошли через процесс принятия решений, мы можем поспешить с разработкой синтаксического анализатора. Вы делали это со мной несколько раз до этого, поэтому вы знаете последовательность: мы начнем с новой копии Cradle и будем добавлять процедуры одна за другой. Так что давайте сделаем это.
Мы начинаем, как и в случае с арифметикой, работая с булевыми литералами а не с переменными. Это дает нам новый вид входного токена, поэтому нам также нужна новая программа распознавания и новая процедура для чтения экземпляров этого типа токенов. Давайте начнем, определив эти две новые процедуры:

Recognize a Boolean Literal
function IsBoolean(c: char): Boolean;
begin
IsBoolean := UpCase(c) in ['T', 'F'];
end;

Get a Boolean Literal
function GetBoolean: Boolean;
var c: char;
begin
if not IsBoolean(Look) then Expected(‘Boolean Literal’);
GetBoolean := UpCase(Look) = ‘T’;
GetChar;
end;

Внесите эти подпрограммы в вашу программу. Вы можете протестировать их, добавив в основную программу оператор печати:
WriteLn(GetBoolean);
Откомпилируйте программу и протестируйте ее. Как обычно пока не очень впечатляет но скоро будет.
Теперь, когда мы работали с числовыми данными, мы должны были организовать генерацию кода для загрузки значений в D0. Нам необходимо сделать то же самое и для булевых данных. Обычным способом кодирования булевых переменных является использование 0 для представления FALSE и какого-либо другого значения для TRUE. Многие языки, как например C, используют для его представления целое число 1. Но я предпочитаю FFFF (или -1) потому что побитовое NOT также возвратит логическое NOT. Итак, нам теперь нужно выдать правильный ассемблерный код для загрузки этих значений. Первая засечка на синтаксическом анализаторе булевых выражений (BoolExpression, конечно):

Parse and Translate a Boolean Expression
procedure BoolExpression;
begin
if not IsBoolean(Look) then Expected(‘Boolean Literal’);
if GetBoolean then
EmitLn(‘MOVE #-1,D0′)
else
EmitLn(‘CLR D0′);
end;

Добавьте эту процедуру в ваш анализатор и вызовите ее из основной программы (заменив оператор печати, который вы только что там поместили). Как вы можете видеть, мы все еще не имеем значительной части синтаксического анализатора, но выходной код начинает выглядеть более реалистичным.
Затем, конечно, мы должны расширить определение булевого выражения. У нас уже есть правило в БНФ:
<b-expression> ::= <b-term> [<orop> <b-term>]*
Я предпочитаю Паскалевскую версию «orop» – OR и XOR. Но так как мы сохраняем односимвольные токены, я буду кодировать их знаками ‘|’ и ‘~’. Следующая версия BoolExpression – почти полная копия арифметической процедуры Expression:

Recognize and Translate a Boolean OR
procedure BoolOr;
begin
Match(‘|’);
BoolTerm;
EmitLn(‘OR (SP)+,D0′);
end;

Recognize and Translate an Exclusive Or
procedure BoolXor;
begin
Match(‘~’);
BoolTerm;
EmitLn(‘EOR (SP)+,D0′);
end;

Parse and Translate a Boolean Expression
procedure BoolExpression;
begin
BoolTerm;
while IsOrOp(Look) do begin
EmitLn(‘MOVE D0,-(SP)’);
case Look of
‘|’: BoolOr;
‘~’: BoolXor;
end;
end;
end;

Обратите внимание на новую процедуру IsOrOp, которая также является копией, на этот раз IsAddOp:

Recognize a Boolean Orop
function IsOrop(c: char): Boolean;
begin
IsOrop := c in ['|', '~'];
end;

ОК, переименуйте старую версию BoolExpression в BoolTerm, затем наберите код, представленный выше. Откомпилируйте и протестируйте эту версию. К этому моменту выходной код начинает выглядеть довольно хорошим. Конечно, нет большого смысла от булевой алгебры над постоянными значениями, но скоро мы расширим булевы типы, с которыми мы работаем.
Возможно вы уже предположили, какой будет следующий шаг: булевская версия Term.
Переименуйте текущую процедуру BoolTerm в NotFactor, и введите следующую новую версию BoolTerm. Заметьте, что она намного более простая, чем числовая версия, так как здесь нет эквивалента деления.

Parse and Translate a Boolean Term
procedure BoolTerm;
begin
NotFactor;
while Look = ‘&’ do begin
EmitLn(‘MOVE D0,-(SP)’);
Match(‘&’);
NotFactor;
EmitLn(‘AND (SP)+,D0′);
end;
end;

Теперь мы почти дома. Мы транслируем сложные булевые выражения, хотя только и для постоянных значений. Следующий шаг – учесть NOT. Напишите следующую процедуру:

Parse and Translate a Boolean Factor with NOT
procedure NotFactor;
begin
if Look = ‘!’ then begin
Match(‘!’);
BoolFactor;
EmitLn(‘EOR #-1,D0′);
end
else
BoolFactor;
end;

И переименуйте предыдущую процедуру в BoolFactor. Теперь испытайте компилятор. К этому времени синтаксический анализатор должен обрабатывать любое булевое выражение, которое вы позаботитесь ему подкинуть. Работает? Отлавливает ли он неправильно сформированные выражения?
Если вы следили за тем, что мы делали в синтаксическом анализаторе для математических выражений вы знаете что далее мы расширили определение показателя для включения переменных и круглых скобок. Мы не должны делать это для булевого показателя, потому что об этих маленьких вещах позаботится наш следующий шаг. Необходима только одна дополнительная строка в BoolFactor, чтобы позаботиться об отношениях:

Parse and Translate a Boolean Factor
procedure BoolFactor;
begin
if IsBoolean(Look) then
if GetBoolean then
EmitLn(‘MOVE #-1,D0′)
else
EmitLn(‘CLR D0′)
else Relation;
end;

Вы могли бы задаться вопросом, когда я собираюсь предоставить булевские переменные и булевские выражения в скобках. Отвечаю: никогда. Помните, ранее мы убрали их из грамматики. Прямо сейчас я собираюсь кодировать грамматику, которую мы уже согласовали. Сам компилятор не может видеть разницы между булевыми переменными или выражениями и арифметическими переменными или выражениями… все это будет обрабатываться в Relation в любом случае.
Конечно, понадобится некоторый код для Relation. Однако, я не чувствую себя комфортно, добавляя еще код, не проверив сперва тот, который мы уже имеем. Так что давайте сейчас просто напишем фиктивную версию Relation, которая ничего не делает за исключением того, что съедает текущий символ и выводит небольшое сообщение:

Parse and Translate a Relation
procedure Relation;
begin
WriteLn(‘<Relation>’);
GetChar;
end;

ОК, наберите этот код и испытайте его. Все старые дела все еще должны работать… у вас должна быть возможность генерировать код для AND, OR и NOT. Кроме того, если вы наберете любой алфавитный символ, вы должны получить небольшой заменитель <Relation>, где должен быть булев показатель. Вы получили это? Отлично, тогда давайте перейдем к полной версии Relation.
Чтобы получить ее, тем не менее, сначала мы должны положить небольшое основание. Вспомните, что отношение имеет форму:
<relation> ::= | <expression> [<relop> <expression]
Так как у нас появился новый вид операторов, нам также понадобится новая логическая функция для ее распознавания. Эта функция показана ниже. Из-за ограничения в один символ, я придерживаюсь четырех операторов, которые могут быть закодированы такими символами («не равно» закодировано как “#”).

Recognize a Relop
function IsRelop(c: char): Boolean;
begin
IsRelop := c in ['=', '#', '<', '>'];
end;

Теперь вспомните, что мы используем нуль или -1 в регистре D0 для представления логического значения и также то, что операторы цикла ожидают, что будет установлен соответствующий флаг. При реализации всего этого для 68000 все становится немного сложным.
Так как операторы цикла выполняются только по флажкам, было бы хорошо (а также довольно эффективно) просто установить эти флажки и совсем ничего не загружать в D0. Это было бы прекрасно для циклов и ветвлений, но запомните, что отношения могут быть использованы везде, где могут быть использованы булевы показатели. Мы можем сохранять его результат в булевой переменной. Так как мы не можем знаеть пока как будет использоваться результат, мы должны учесть оба случая.
Сравнение числовых данных достаточно просто… 68000 имеет команду для этого… но она устанавливает флажки а не значение. Более того, всегда будут устанавливаться те же самые флажки (ноль если равно, и т.д.), в то время, как нам необходим по-разному установленный флажок нуля для каждого различного оператора отношения.
Решение заключается в инструкции Scc процессора 68000, которая устанавливает значение байта в 0000 или FFFF (забавно как это работает!) в зависимости от результата определенного условия. Если мы сделаем байтом результата регистр D0, мы получим необходимое логическое значение.
К сожалению, имеется одно заключительное осложнение: в отличие от почти всех других команд в наборе 68000, Scc не сбрасывает флажки условий в соответствии с сохраняемыми данными. Поэтому мы должны сделать последний шаг, проверить D0 и установить соответствующим образом флажки. Это должно быть похоже на оборот вокруг луны для получения того, что мы хотим: мы сначала выполняем проверку, затем проверяем флажки, чтобы установить данные в D0, затем тестируем D0 чтобы установить флажки снова. Это окольный путь, но это самый простой способ получить правильные флажки и, в конце концов, это всего лишь пара инструкций.
Я мог бы упомянуть здесь, что эта область, по моему мнению, показывает самые большие различия между эффективностью вручную написанного на ассемблере и сгенерированного компилятором кода. Мы уже видели, что мы теряем эффективность при арифметических операциях, хотя позже я планирую показать вам как ее немного улучшить. Мы также видели, что управляющие конструкции сами по себе могут быть реализованы довольно эффективно… обычно очень сложно улучшить код, сгенерированный для IF или WHILE. Но практически каждый компилятор, который я когда-либо видел, генерирует ужасный код, по сравнению с ассемблером, для вычисления булевых функций и особенно отношений. Причина как раз в том, о чем я упомянул выше. Когда я пишу код на ассемблере, я двигаюсь вперед и выполняю проверку наиболее удобным для меня способом, и затем подготавливаю ветвление так чтобы переход был выполнен на нужную ветку. Фактически, я «подстраиваю» каждое ветвление под ситуацию. Компилятор не может сделать этого (практически) и он также не может знать, что нам не нужно сохранять результат проверки как булевскую переменную. Поэтому он должен генерировать код по очень строгим правилам и часто заканчивает сохранением результата как булевой переменной, которая никогда не будет использована для чего-либо.
В любом случае мы теперь готовы рассмотреть код для Relation. Он показан ниже с сопровождающими процедурами:

Recognize and Translate a Relational «Equals»
procedure Equals;
begin
Match(‘=’);
Expression;
EmitLn(‘CMP (SP)+,D0′);
EmitLn(‘SEQ D0′);
end;

Recognize and Translate a Relational «Not Equals»
procedure NotEquals;
begin
Match(‘#’);
Expression;
EmitLn(‘CMP (SP)+,D0′);
EmitLn(‘SNE D0′);
end;

Recognize and Translate a Relational «Less Than»
procedure Less;
begin
Match(‘<’);
Expression;
EmitLn(‘CMP (SP)+,D0′);
EmitLn(‘SGE D0′);
end;

Recognize and Translate a Relational «Greater Than»
procedure Greater;
begin
Match(‘>’);
Expression;
EmitLn(‘CMP (SP)+,D0′);
EmitLn(‘SLE D0′);
end;

Parse and Translate a Relation
procedure Relation;
begin
Expression;
if IsRelop(Look) then begin
EmitLn(‘MOVE D0,-(SP)’);
case Look of
‘=’: Equals;
‘#’: NotEquals;
‘<’: Less;
‘>’: Greater;
end;
EmitLn(‘TST D0′);
end;
end;

Теперь этот вызов Expression выглядит знакомым! Вот где редактор вашей системы оказывается полезным. Мы уже генерировали код для Expression и его близнецов на предыдущих уроках. Теперь вы можете скопировать их в ваш файл. Не забудьте использовать односимвольную версию. Просто чтобы быть уверенным, я продублировал арифметические процедуры ниже. Если вы наблюдательны, вы также увидите, что я их немного изменил чтобы привести в соответствие с последней версией синтаксиса. Эти изменения не являются необходимыми, так что вы можете предпочесть оставить все как есть до тех пор, пока не будете уверены, что все работает.

Parse and Translate an Identifier
procedure Ident;
var Name: char;
begin
Name:= GetName;
if Look = ‘(‘ then begin
Match(‘(‘);
Match(‘)’);
EmitLn(‘BSR ‘ + Name);
end
else
EmitLn(‘MOVE ‘ + Name + ‘(PC),D0′);
end;

Parse and Translate a Math Factor
procedure Expression; Forward;
procedure Factor;
begin
if Look = ‘(‘ then begin
Match(‘(‘);
Expression;
Match(‘)’);
end
else if IsAlpha(Look) then
Ident
else
EmitLn(‘MOVE #’ + GetNum + ‘,D0′);
end;

Parse and Translate the First Math Factor
procedure SignedFactor;
begin
if Look = ‘+’ then
GetChar;
if Look = ‘-’ then begin
GetChar;
if IsDigit(Look) then
EmitLn(‘MOVE #-’ + GetNum + ‘,D0′)
else begin
Factor;
EmitLn(‘NEG D0′);
end;
end
else Factor;
end;

Recognize and Translate a Multiply
procedure Multiply;
begin
Match(‘*’);
Factor;
EmitLn(‘MULS (SP)+,D0′);
end;

Recognize and Translate a Divide
procedure Divide;
begin
Match(‘/’);
Factor;
EmitLn(‘MOVE (SP)+,D1′);
EmitLn(‘EXS.L D0′);
EmitLn(‘DIVS D1,D0′);
end;

Parse and Translate a Math Term
procedure Term;
begin
SignedFactor;
while Look in ['*', '/'] do begin
EmitLn(‘MOVE D0,-(SP)’);
case Look of
‘*’: Multiply;
‘/’: Divide;
end;
end;
end;

Recognize and Translate an Add
procedure Add;
begin
Match(‘+’);
Term;
EmitLn(‘ADD (SP)+,D0′);
end;

Recognize and Translate a Subtract
procedure Subtract;
begin
Match(‘-’);
Term;
EmitLn(‘SUB (SP)+,D0′);
EmitLn(‘NEG D0′);
end;

Parse and Translate an Expression
procedure Expression;
begin
Term;
while IsAddop(Look) do begin
EmitLn(‘MOVE D0,-(SP)’);
case Look of
‘+’: Add;
‘-’: Subtract;
end;
end;
end;

Теперь вы получили что-то… синтаксический анализатор, который может обрабатывать и арифметику и булеву алгебру и их комбинации через использование операторов отношений. Я советую вам сохранить копию этого синтаксического анализатора в безопасном месте для будущих обращений, потому что на нашем следующем шаге мы собираемся разделить его.