Reklama

Оператор BREAK

Ранее я обещал вам оператор BREAK для сопровождения цикла LOOP. Им я в некотором роде горд. На первый взгляд BREAK кажется действительно сложным. Моим первым подходом было просто использовать его как дополнительный ограничитель в Block и разделить все циклы на две части точно также как я сделал это для ELSE оператора IF. Но, оказывается, это не работает, потому что оператор BREAK редко находится на том же самом уровне, что и сам цикл. Наиболее вероятное место для BREAK – сразу после IF, что приводило бы к выходу из конструкции IF, а не из окружающего цикла. Неправильно. BREAK должен выходить из внутреннего LOOP даже если он вложен в несколько уровней IF.
Моей следующей мыслью было просто сохранять в какой-то глобальной переменной, метку окончания самого вложенного цикла. Это также не работает, потому что может возникнуть прерывание из внутренного цикла с последующим прерыванием из внешнего. Сохранение метки для внутреннего цикла затерло бы метку для внешного. Так глобальная переменная превратилась в стек. Дело становилось грязным.
Тогда я решил последовать своему собственному совету. Помните последний урок, когда я показал вам как хорошо служит нам неявный стек синтаксического анализатора с рекурсивным спуском. Я сказал, что если вы начинаете видеть потребность во внешнем стеке, возможно вы делаете что-то неправильно. Действительно возможно заставить рекурсию, встроенную в наш синтаксический анализатор, позаботиться обо всем и это решение настолько простое, что кажется удивительным.
Секрет состоит в том, чтобы заметить, что каждый оператор BREAK должен выполняться внутри блока… и ни в каком другом месте. Так что все, что мы должны сделать это передать в Block адрес выхода из самого внутреннего цикла. Затем он может передать этот адрес подпрограмме, транслирующей инструкцию Break. Так как оператор IF не изменяет уровень цикла, процедура DoIf не должна делать что-либо за исключением передачи метки в ее блок (оба из них). Так как циклы изменяют уровень, каждый цикл просто игнорирует любую метку выше его и передает свою собственную метку выхода дальше.
Все это проще показать вам чем описывать. Я продемонстрирую это с самым простым циклом, циклом LOOP:

Parse and Translate a LOOP Statement
procedure DoLoop;
var L1, L2: string;
begin
Match(‘p’);
L1 := NewLabel;
L2 := NewLabel;
PostLabel(L1);
Block(L2);
Match(‘e’);
EmitLn(‘BRA ‘ + L1);
PostLabel(L2);
end;

Заметьте, что теперь DoLoop имеет две метки а не одну. Вторая дает команде BREAK адрес перехода Если в цикле нет BREAK, то мы зря потратили метку и немного загромоздили код, но не нанесли никакого вреда.
Заметьте также, что процедура Block теперь имеет параметр, который для циклов всегда будет адресом выхода. Новая версия Block:

Recognize and Translate a Statement Block
procedure Block(L: string);
begin
while not(Look in ['e', 'l', 'u']) do begin
case Look of
‘i’: DoIf(L);
‘w’: DoWhile;
‘p’: DoLoop;
‘r’: DoRepeat;
‘f’: DoFor;
‘d’: DoDo;
‘b’: DoBreak(L);
else Other;
end;
end;
end;

Снова заметьте, что все что Block делает с меткой это передает ее в DoIf и DoBreak. Циклы не нуждаются в ней, потому что они в любом случае передают свою собственную метку.
Новая версия DoIf:

Recognize and Translate an IF Construct
procedure Block(L: string); Forward;
procedure DoIf(L: string);
var L1, L2: string;
begin
Match(‘i’);
Condition;
L1 := NewLabel;
L2 := L1;
EmitLn(‘BEQ ‘ + L1);
Block(L);
if Look = ‘l’ then begin
Match(‘l’);
L2 := NewLabel;
EmitLn(‘BRA ‘ + L2);
PostLabel(L1);
Block(L);
end;
Match(‘e’);
PostLabel(L2);
end;

Здесь единственное, что изменяется, это добавляется параметр у процедуры Block. Оператор IF не меняет уровень вложенности цикла, поэтому DoIf просто передает метку дальше. Независимо от того, сколько уровней вложенности IF мы имеем, будет использоваться та же самая метка.
Теперь не забудьте, что DoProgram также вызывает Block и теперь необходимо передавать ей метку. Попытка выхода из внешнего блока является ошибкой, поэтому DoProgram передает пустую метку, которая перехватывается DoBreak:

Recognize and Translate a BREAK
procedure DoBreak(L: string);
begin
Match(‘b’);
if L <> ” then
EmitLn(‘BRA ‘ + L)
else Abort(‘No loop to break from’);
end;

Parse and Translate a Program
procedure DoProgram;
begin
Block(”);
if Look <> ‘e’ then Expected(‘End’);
EmitLn(‘END’)
end;

Этот код позаботится почти обо всем. Испытайте его, посмотрите, сможете ли вы «сломать» («break») его (каламбур). Аккуратней однако. К настоящему времени мы использовали так много букв, что трудно придумать символ, который не представляет сейчас какое либо зарезервированное слово. Не забудьте, перед тем, как вы протестируете программу, вы должны будете исправить каждый случай появления Block в других циклах для включения нового параметра. Сделайте это точно так же, как я сделал это для LOOP.
Я сказал выше «почти». Есть одна небольшая проблема: если вы внимательно посмотрите на код, генерируемый для DO, вы увидите, что если вы прервете этот цикл, то значение счетчика все еще остается в стеке. Мы должны исправить это! Позор… это была одна из самых маленьких наших подпрограмм, но это не помогло. Вот новая версия, которая не имеет этой проблемы:

Parse and Translate a DO Statement
procedure Dodo;
var L1, L2: string;
begin
Match(‘d’);
L1 := NewLabel;
L2 := NewLabel;
Expression;
EmitLn(‘SUBQ #1,D0′);
PostLabel(L1);
EmitLn(‘MOVE D0,-(SP)’);
Block(L2);
EmitLn(‘MOVE (SP)+,D0′);
EmitLn(‘DBRA D0,’ + L1);
EmitLn(‘SUBQ #2,SP’);
PostLabel(L2);
EmitLn(‘ADDQ #2,SP’);
end;

Две дополнительные инструкции SUBQ и ADDQ заботятся о сохранении стека в правильной форме.

Reklama